Convert your buttons to BMPs keeping transparency with GdiPlusX

Thee function below converts any button image to a bmp to be used in VFP forms.

There are lots of cool and free icons available on the web, but the vast majority are in .ico, gif or png image formats, that are not very familiar and reliable to be used in vfp. for us, the best image format, for a lot of reasons, is the BMP format.

Some transformations are needed to make this bmp to show exactly how we desire, specially when converting source images in a png, gif or ico formats.

VFP shows the pure white - RGB(255,255,255) as transparent in our buttons and image objects. the code below first converts the original whites to RGB(254,254,254) that is visually the same, but does not become transparent, and eliminates the need to create a mask image (.MSK) and next, converts the background color of the original bitmap to pure white, that will show transparent in VFP forms.

For more details, check these prior posts:
bmps with transparent backgrounds
how to put one image over another in a form


Important requires VFP9 and GdiplusX to run.

Save the program below as BUTTON2BMP.PRG, and call it this way:

BUTTON2BMP(GETPICT(), "c:\NewIcon.BMP")

When you compile this program in your executable, please don't forget to remove the LOCFILE() command, and just use a "do system.prg" instead

lparameters tcsourcefile, tcdestfile

do locfile("system.app")

local lobmp as xfcbitmap
local logfx as xfcgraphics
local loborderclr as xfccolor
local lorect as xfcrectangle
local loattr as xfcimageattributes
local locolormap as xfccolormap

with _screen.system.drawing
   locolormap = .imaging.colormap.new()
   loattr = .imaging.imageattributes.new()

   lobmp = .bitmap.fromfile(tcsourcefile)

   logfx = .graphics.fromimage(lobmp)

   lorect = lobmp.getbounds()

   * get the top left pixel color, presuming this color is the background colro to become transparent
   *    for our bmp case, this will become pure white  - rgb(255,255,255)
   *    that becomes transparent when used in vfp objects
   loborderclr = lobmp.getpixel(0,0)

   * convert original whites rgb(255,255,255) to off white - rgb(254,254,254)
   * this way, the whites will remain without the need of a mask
   locolormap.oldcolor = .color.white
   locolormap.newcolor = .color.fromargb(255,254,254,254)

   loattr.setremaptable(locolormap)
   logfx.drawimage(lobmp, lorect, lorect, .graphicsunit.pixel, loattr)

   * next step, convert the borders to pure white, rgb(255,255,255) that will become transparent in buttons
   locolormap.oldcolor = loborderclr
   locolormap.newcolor = .color.white
   loattr.setremaptable(locolormap)
   logfx.drawimage(lobmp, m.lorect, m.lorect, .graphicsunit.pixel, loattr)

   lobmp.save(tcdestfile, .imaging.imageformat.bmp)
endwith